animal taming macro

General Macro Help animal taming macro

Viewing 18 posts - 1 through 18 (of 18 total)
  • Author
    Posts
  • #877
    darkjedi
    Member
      • Topics - 1
      • Replies - 6
      • Total - 7
      • Neophyte

      Guys, can anybody help me with a taming macro?

      In old ZH shards, you had to mount and dismount the animal to train taming appropriately.

      Does it work this way here?

      If positive, can anybody help me with a macro.

      I tryed one easy uo macro, but it´s not working good.

      Thanks in advance.

      #878
      lonewolf
      Member
        • Topics - 16
        • Replies - 56
        • Total - 72
        • Journeyman
        • ★★★★

        Mounting worked last time I tried, but I used ress/kill instead.

        This is an old macro I had on another shard for mount/dismount tame. It might not be super stable though in case you anger your pet or something, fyi. Heavenly ostards cannot be angered afaik.
        https://drive.google.com/open?id=0B5x_NQz3CXmXSjd4dFZCNEstb00

        #879
        darkjedi
        Member
          • Topics - 1
          • Replies - 6
          • Total - 7
          • Neophyte

          It´s now working, because when you mount and dismount the targetid changes, and the script does not work.

          #880
          darkjedi
          Member
            • Topics - 1
            • Replies - 6
            • Total - 7
            • Neophyte

            It´s not working****

            #881
            lonewolf
            Member
              • Topics - 16
              • Replies - 56
              • Total - 72
              • Journeyman
              • ★★★★
              #882
              darkjedi
              Member
                • Topics - 1
                • Replies - 6
                • Total - 7
                • Neophyte

                It´s the same

                #883
                mappi
                Member
                  • Topics - 0
                  • Replies - 1
                  • Total - 1
                  • Neophyte

                  If you know your way around EasyUO, you should be able to use this.
                  m_omega_taming_v3.txt
                  just put bows/arrows/bandages in your backpack, let it set the .arm1-5, then go stand near your trapped npc of choice.
                  Im on discord if it doesnt work.

                  #2308
                  sharnthor
                  Member
                    • Topics - 21
                    • Replies - 90
                    • Total - 111
                    • Expert
                    • ★★★★★

                    mappi. Is it possible to upload again please? I am in need of a taming script

                    #2416
                    jogzgs
                    Member
                      • Topics - 12
                      • Replies - 9
                      • Total - 21
                      • Novice
                      • ★★

                      Can someone please help with a UOS macro to do taming

                      Please and thanks

                      #2457
                      sharnthor
                      Member
                        • Topics - 21
                        • Replies - 90
                        • Total - 111
                        • Expert
                        • ★★★★★

                        jogzgs. just use easyuo

                        #2862
                        sharnthor
                        Member
                          • Topics - 21
                          • Replies - 90
                          • Total - 111
                          • Expert
                          • ★★★★★

                          So, mappy gave me this script – mappi, so sorry if you you didnt’ want this on here, but it’s an awesome script 🙂

                          ;---------------------------------------------------------------------;
                          ;--program------------------------------------------------------------;
                          ;---------------------------------------------------------------------;
                          
                          gosub thesetup
                          
                          start:
                          gosub findanimal %animaltype
                          gosub tameanimal
                          gosub killanimal
                          gosub ressanimal #result
                          if %timerz < #scnt
                             {
                             gosub rescount
                             set %timerz ( #scnt + %zdelay )
                             }
                          goto start
                          
                          ;----------------------------------------------------------------;
                          
                          sub thesetup
                          
                          set %spectre HIM
                          set %zdelay 200  ;change this to change how many secs delay it spams the resource count
                          set %lootcorpses 0   ;set to 1 for animals with loot
                          set %killangry 1    ;set to 1 to save time by killing angered animals
                          
                          finditem RWF C_ , #backpackid       ;checks for arrows in your backpack
                          if #findcnt > 0
                             {
                             for #findindex 1 #findcnt
                                 {
                                 set %arrowsn ( %arrowsn + #findstack )
                                 }
                             set %arrows #findid
                             event sysmessage Arrows: %arrowsn
                             }
                          else
                              {
                              set %display no_arrows
                              gosub stop %display
                              }
                          wait 10
                          finditem LNK C_ , #backpackid       ;checks for bolts in your backpack
                          if #findcnt > 0
                             {
                             set %bolts #findid
                             event sysmessage Bolts: #findstack
                             }
                          else
                              {
                              set %display no_bolts
                              gosub stop %display
                              }
                          wait 10
                          finditem ZLF C_ , #backpackid       ;checks for bandages in your backpack
                          if #findcnt > 0
                             {
                             set %bandages #findid
                             event sysmessage Bandages: #findstack
                             }
                          else
                              {
                              set %display no_bandages
                              gosub stop %display
                              }
                          wait 10
                          finditem WOH_JSF C_ , #charid        ;checks for bows and/or crossbows in your backpack and disarms
                          if #findcnt > 0
                             {
                             msg .disarm $
                             wait 10
                             }
                          wait 10
                          finditem WOH_JSF C_ , #backpackid     ;checks for bows and crossbows in your backpack to count
                          if #findcnt > 0
                             {
                             set %numbows #findcnt
                             for #findindex 1 #findcnt
                                 {
                                 set %bow . #findindex #findid
                                 }
                             event sysmessage Bows: %numbows
                             }
                          else
                              {
                              set %error No , #spc , Bows , #spc , Found , #spc , at , #spc , backpack
                              gosub stop %error
                              }
                          if %numbows > 5
                             {
                             set %numbows 5
                             }
                          display yesnocancel Setup .Arm Commands? No to Proceed. Cancel to quit.
                          if #dispres = yes
                             {
                             gosub setupbows
                             }
                          if #dispres = cancel
                             {
                             event sysmessage stopping script!
                             halt
                             }
                          set #dispres nothing
                          event sysmessage Target the trapped animal   ;target the animal you'll be training on
                          set #targcurs 1
                          while #targcurs = 1
                                {
                                wait 2
                                }
                          set %tempvar #ltargetid
                          wait 10
                          finditem %tempvar G_5
                          if #findcnt > 0
                             {
                             set %animaltype #findtype
                             event ExMsg #findid 0 33 I am type: #findtype
                             }
                          else
                              {
                              set %error no_animal_found
                              gosub stop %error
                              }
                          finditem FQD c_ , #backpackid         ;checks if you have raw fish in your backpack (food ofcourse)
                          if #findcnt > 0
                             {
                             set %fisk #findid
                             event sysmessage #findstack fishs
                             }
                          else
                              {
                              event sysmessage No fishs
                              }
                          finditem PEF_SEF c_ , #backpackid      ;checks if you have kindling in your backpack
                          if #findcnt > 0
                             {
                             set %kindling #findid
                             event sysmessage #findstack kindlings
                             }
                          else
                              {
                              event sysmessage No Kindling!
                              }
                          set %display 0
                          set %timerz ( #scnt + %zdelay )
                          set %moveawayx 1273
                          set %moveawayy 1287
                          skippast:
                          return
                          
                          ;---------------Set Up Your Bows Arm/Disarm-------------------------------------;
                          
                          sub setupbows
                          set %xbutton 75
                          set %ybutton 330
                          set %x 45
                          
                          finditem WOH_JSF C_ , #charid
                          if #findcnt > 0
                             {
                             msg .disarm $
                             wait 10
                             }
                          wait 10
                          finditem WOH_JSF C_ , #backpackid
                          if #findcnt > 0
                             {
                             set %numbows #findcnt
                             for #findindex 1 #findcnt
                                 {
                                 set %bow . #findindex #findid
                                 }
                             event sysmessage Bows: %numbows
                             }
                          else
                              {
                              set %error ( No , #spc , Bows , #spc , Found , #spc , within , #spc , your , #spc , backpack )
                              gosub stop %error
                              }
                          if %numbows > 5
                             {
                             set %numbows 5
                             }
                          event sysmessage Setting Arm commands
                          msg .arm$
                          set %bii 1
                          for %bii 1 %numbows
                              {
                              event sysmessage Arming bow %bii DontCrash
                              ExEvent drag %bow . %bii
                              wait 25
                              ExEvent droppd
                              wait 25
                              finditem WOH C_ , #charid
                              if #findcnt > 0
                                 {
                                 set %yy ( ( 50 * %bii ) + 25 )
                                 click %x %yy
                                 wait 18
                                 click %xbutton %ybutton
                                 wait 18
                                 msg .disarm$
                                 wait 18
                                 }
                              }
                          click %xbutton %ybutton r
                          event sysmessage All your bows are set up
                          return
                          
                          ;----------------Find Your Animal------------------------------------------------;
                          
                          sub findanimal
                          refind:
                          wait 10
                          finditem %1 G_4   ; YG = bull
                          if #findcnt > 0
                             {
                             set %liveanimal #findid
                             wait 6
                             }
                          else
                              {
                              event sysmessage No animals detected
                              }
                          return
                          
                          ;------------------Tame The Animal -----------------------------------------------;
                          
                          sub tameanimal
                          set #ltargetid %spectre
                          event macro 27 0
                          retame:
                          event macro 13 35
                          set #ltargetkind 1
                          set #ltargetid %liveanimal
                          set %jstart #jindex
                          target 2s
                          event macro 22 0
                          wait 1s
                          scanjournal
                          if does_not_seem in #journal
                             {
                             return
                             }
                          if tamed_already in #journal
                             {
                             return
                             }
                          if has_angered in #journal
                             {
                             event sysmessage Animal is angry
                             if %killangry = 0
                                {
                                wait 14s
                                goto retame
                                }
                             return
                             }
                          else
                              {
                              wait 10s
                              set %jend #jindex
                              event sysmessage scanning...
                              for %ji %jstart %jend
                                  {
                                  scanjournal %ji
                                  if tamed_already in #journal
                                     {
                                     return
                                     }
                                  if successfully_tame in #journal
                                     {
                                     event sysmessage success
                                     return
                                     }
                                  if failed_to_tame in #journal
                                     {
                                     set %ji %ji + 1
                                     scanjournal %ji
                                     if unresponsive in #journal
                                        {
                                        event sysmessage One loop of tracking to reset cd
                                        wait 4s
                                        gosub trackingonce
                                        goto retame
                                        }
                                     event sysmessage Not successfull will retry in 4s
                                     wait 4s
                                     goto retame
                                     }
                                  }
                              event sysmessage retrying because no recognised journal entry
                              wait 4s
                              goto retame
                              }
                          return
                          
                          ;---------------------Kill the animal---------------------------------------------;
                          
                          sub killanimal
                          msg all release$
                          set %liveanimal #ltargetid
                          event macro 27 0
                          gosub rearm
                          set %timera ( #scnt + 68 )
                          set %timerc ( #scnt + 10 )
                          set #lobjectid %fisk
                          repeat
                                {
                                if %timera < #scnt
                                   {
                                   finditem %liveanimal G_3
                                   if #findcnt > 0
                                      {
                                      event sysmessage Timed out but animal is alive
                                      gosub killanimal
                                      }
                                   }
                                if %timerc < #scnt
                                   {
                          ;         event macro 13 38
                          ;         wait 1s
                          ;SET %clickX #CONTPOSX + %1
                          ;SET %clickY #CONTPOSY + %2
                          ;CLICK %clickX %clickY
                          ;         wait 5s
                          ;         set %timerc ( #scnt + 10 )
                                   }
                                event macro 17 0   ;does a fisk
                                wait 3s
                                     ignoreitem reset 1
                                     ignoreitem MXNVNMD 1
                                     ignoreitem JRNMGOD   1  ;corspes
                                     ignoreitem HAOMGOD   1   ;ignore player corpses
                                finditem YFM G_3
                                wait 5
                                }
                          until #findcnt > 0
                          
                          set #ltargetid %spectre
                          event macro 27 0
                          return #findid
                          ;------------------------------------------------------------------
                          sub rearm
                          event sysmessage arming
                          msg $
                          msg .arm 1$
                          wait 2
                          msg .arm 2$
                          wait 2
                          msg .arm 3$
                          ;msg .arm 4$
                          ;msg .arm 5$
                          return
                          ;-------------------------------------------------------------------
                          sub trackingonce
                          ;event macro 13 13
                          ;wait 1s
                          ;SET %clickX #CONTPOSX + %1
                          ;SET %clickY #CONTPOSY + %2
                          ;CLICK %clickX %clickY
                          wait 10s
                          return
                          ;--------------------------------------------------------------------
                          sub ressanimal
                          ;event pathfind #findx #findy
                          ;wait 8
                          ;set #lobjectid %dagger      ;comment out to remove skinning
                          ;event macro 17 0            ;
                          ;target 2s                   ;
                          ;set #ltargetid #contid      ;
                          ;event macro 22 0            ;
                          wait 5                       ;end
                          if G in #charstatus
                             {
                             event macro 6
                             }
                          if %lootcorpses = 1
                             {
                             gosub loot %1
                             }
                          reress:
                          set %jstart #jindex
                          set #lobjectid %bandages
                          event macro 17 0
                          target 2s
                          set #ltargetid %1
                          event macro 22 0
                          wait 1s
                          scanjournal
                          if does_not_seem in #journal
                             {
                             return
                             }
                          wait 11s
                          set %jend #jindex
                          for %jii %jstart %jend
                              {
                              scanjournal %jii
                              if resurrected_a in #journal
                                 {
                                 return
                                 }
                              if fail_to_ress in #journal
                                 {
                                 goto reress
                                 }
                              }
                          goto reress
                          return
                          ;-------------------------------------------------------------------------;
                          sub loot
                          if #finddist > 1
                             {
                             event pathfind #findx #findy #findz
                             wait 12
                             }
                          set #lobjectid %1
                          event macro 17 0
                          wait 20
                          finditem RWF_LNK_POF_WZF_OWI_RVH_DAG_QZF_HUF_VUF_MWF_WOH C_ , %1
                          event sysmessage Looting #findcnt items...
                          for #findindex 1 #findcnt
                              {
                              exevent drag #findid #findstack
                              wait 12
                              exevent dropc #backpackid
                              wait 12
                              }
                          return
                          ;-------------------------------------------------------------------------;
                          sub rescount
                          set %arrowsn 0
                          finditem WOH C_ , #backpackid
                                   {
                                   set %numbows #findcnt
                                   }
                          wait 1
                          finditem RWF C_ , #backpackid
                          if #findcnt > 0
                             {
                             for #findindex 1 #findcnt
                                 {
                                 set %arrowsn ( %arrowsn + #findstack )
                                 }
                             }
                          finditem %bandages C_ , #backpackid
                                   {
                                   set %nbandages #findstack
                                   }
                          finditem %fisk C_ , #backpackid
                                   {
                                   set %nfisk #findstack
                                   }
                          event sysmessage Bows: %numbows / Arrows: %arrowsn / Bandages: %nbandages / Fish: %nfisk
                          wait 1
                          return
                          ;-------------------------------------------------------------------------;
                          sub stop
                          display ok %1
                          return
                          ;-------------------------------------------------------------------------;
                          #3291
                          willowleaf
                          Member
                            • Topics - 7
                            • Replies - 25
                            • Total - 32
                            • Novice
                            • ★★

                            so do you have to kill the mount and ress to get gains..or can you just mount and dismount, all release, and tame again?

                            #3292
                            krynn
                            Member
                              • Topics - 3
                              • Replies - 38
                              • Total - 41
                              • Apprentice
                              • ★★★

                              You can tame, mount, dismount and all release and repeat process @willowleaf.

                              #3294
                              sharnthor
                              Member
                                • Topics - 21
                                • Replies - 90
                                • Total - 111
                                • Expert
                                • ★★★★★

                                Best is to kill it though. You gain archery at the same time

                                #3310
                                willowleaf
                                Member
                                  • Topics - 7
                                  • Replies - 25
                                  • Total - 32
                                  • Novice
                                  • ★★

                                  can you do it with razor? or do I need Easy UO. and if it is easy UO can anyone be helpful and send me the script? I have never used that program before and cant even begin to understand how it works

                                  thanks.

                                  #3345
                                  sharnthor
                                  Member
                                    • Topics - 21
                                    • Replies - 90
                                    • Total - 111
                                    • Expert
                                    • ★★★★★

                                    You’re gonna have to create your own in razor if you need it it seems.

                                    I won’t use razor though, I believe that it won’t be able to tame and kill the animal – I might be wrong here though.

                                    Just run UO with UOS, log in to your ranger. Once in, open up Easy UO. Open up the script and press play – VERY simple.

                                    Also, you need to have a specific version of Easy UO to work on this shard – V 1.5.1.309

                                    #3346
                                    schaukoski
                                    Member
                                      • Topics - 2
                                      • Replies - 9
                                      • Total - 11
                                      • Neophyte

                                      Hi Sharnthor, thanks for the macro man, im gonna try that!

                                      Do you know how to train veterinary on this shard?

                                      Thanks man!

                                      #3825
                                      sharnthor
                                      Member
                                        • Topics - 21
                                        • Replies - 90
                                        • Total - 111
                                        • Expert
                                        • ★★★★★

                                        Yo, no worries.

                                        Yeah, just run the script above 🙂

                                        It tames, releases, kills, vets – then starts all over again. This will max your vet before taming

                                      Viewing 18 posts - 1 through 18 (of 18 total)
                                      • You must be logged in to reply to this topic.